home *** CD-ROM | disk | FTP | other *** search
/ Compendium Deluxe 2 / LSD and 17bit Compendium Deluxe - Volume II.iso / a / prog / asmsrc / meltdown.lha / INTRO-1 / Composer.s next >
Encoding:
Text File  |  1988-07-19  |  20.1 KB  |  1,062 lines
  1. *****************************************************************************
  2. *                                                                           *
  3. *                             New Intro For Arena                           *
  4. *                                                                           *
  5. *  Start Date : 23/3/91                                                     *
  6. * Last Update : 01/4/91                                                     *
  7. *                                     Code : Slaine *
  8. *                                                                           *
  9. *****************************************************************************
  10.  
  11. ; Include the macros
  12.  
  13.     Incdir    Df1:
  14.     Include    Source/Macro
  15.  
  16. *****************************************************************************
  17.  
  18. FadeSpeed    =    1
  19. ScrollSpeed    =    3
  20.  
  21. *****************************************************************************
  22.  
  23. ; Dont forget to use chip ram
  24.  
  25.     Chip
  26.     
  27. *****************************************************************************
  28.  
  29. ; Kill the operating system for good mesure
  30.  
  31.     Kill        
  32.     
  33. *****************************************************************************
  34.  
  35. ; Init Sprites
  36.     Move.l    #Sprite,D0
  37.     PlaneOn    D0,Spr0l+2,Spr0h+2
  38.     Move.l    #Sprite1,D0
  39.     PlaneOn    D0,Spr1l+2,Spr1h+2
  40.     Move.l    #Sprite2,D0
  41.     PlaneOn    D0,Spr2l+2,Spr2h+2
  42.  
  43. *****************************************************************************
  44.  
  45. ; Load custom and set up copper list
  46.  
  47.     Lea    Custom,A5
  48.     Move.l    #Copper,Cop1lch(a5)
  49.     Move.w    #%1000011111100000,Dmacon(a5)    
  50.     
  51. *****************************************************************************
  52.  
  53. ; Clear Some Memory
  54.  
  55.     Blitwait
  56.     Move.l    #$70000,Bltdpth(a5)
  57.     Move.l    #-1,Bltafwm(a5)
  58.     Move.w    #0,Bltdmod(a5)
  59.     Move.l    #$01000000,Bltcon0(a5)
  60.     Move.w    #512*64+60,Bltsize(a5)
  61.  
  62. *****************************************************************************
  63.  
  64.     Blitwait
  65.     
  66. *****************************************************************************
  67.  
  68.     Lea    LogoBits+2,A0
  69.     Moveq    #3-1,d7
  70.     Move.l    #Logo,D0
  71. LogoB
  72.     Move.w    d0,(a0)
  73.     Addq    #4,a0
  74.     Swap    d0
  75.     Move.w    d0,(a0)
  76.     Addq    #4,a0
  77.     Swap    d0
  78.     Add.l    #70*40,d0
  79.     Dbf    D7,LogoB
  80.  
  81. *****************************************************************************
  82.  
  83.     SaveAll
  84.     Jsr    BpInit
  85.     LoadAll
  86.     
  87. *****************************************************************************
  88.  
  89. ; Main routine here
  90.  
  91. Mouse
  92.     Cmp.b    #$c0,$dff006
  93.     Bne.s    Mouse
  94.     Bsr    Feild
  95.     Bsr    SetNights
  96.     Bsr    Fading
  97.     Bsr    Riders
  98.     Eor.l    #$5000,ScreenPtr
  99.     Eor.l    #$5000,Buff1
  100.     Eor.l    #$5000,Buff2
  101.     Bsr    Clear
  102.     Bsr    DoScroll
  103.     SaveAll
  104.     Jsr    BpMusic
  105.     LoadAll
  106.     Tstmice    Mouse                ; Pressed the mouse
  107.     
  108. *****************************************************************************
  109.  
  110.      clr.w    $dff0a8
  111.     clr.w    $dff0b8
  112.     clr.w    $dff0c8
  113.     clr.w    $dff0d8
  114.     move.w    #$f,$dff096
  115.  
  116. *****************************************************************************
  117.  
  118.     Move.l    #50,D6
  119. EndLoop
  120.     Pos
  121.     SaveAll
  122.     Bsr    SetNights1
  123.     Move.l    #FadeDown,A1
  124.     Lea    SnurkCol+2,a0
  125.     Move.l    #3-1,D7
  126.     Move.l    #0,D6
  127.     Move.l    #4,D5
  128.     Bsr    FadeLoop
  129.     Move.l    #FadeDown,A1
  130.     Lea    Nit+6,a0
  131.     Move.l    #84-1,D7
  132.     Move.l    #8,D5
  133.     Move.l    #0,D6
  134.     Bsr    FadeLoop
  135.     Lea    BlueFade+2,A0
  136.     Move.l    #FadeDown,A1
  137.     Move.l    #6-1,d7
  138.     Move.l    #0,d6
  139.     Move.l    #4,d5
  140.     Bsr    FadeLoop
  141.  
  142.     LoadAll
  143.  
  144.     Dbf    D6,EndLoop
  145.     
  146. *****************************************************************************
  147.  
  148. ; Return operating system and go back to user
  149.  
  150.     Heal
  151.     Clr.l    D0                ; No error
  152.     Rts
  153.     
  154. *****************************************************************************
  155.  
  156. Feild
  157.     Lea    Sprite+1,A0
  158.     Move.l    #9,d7
  159. SpriteLoop1
  160.     Add.b    #3,(A0)
  161.     Add.w    #24,a0
  162.     Add.b    #4,(A0)
  163.     Add.w    #24,a0
  164.     Dbf    D7,SpriteLoop1
  165.     Lea    Sprite1+1,A0
  166.     Move.l    #9,d7
  167. SpriteLoop2
  168.     Add.b    #2,(A0)
  169.     Add.w    #24,a0
  170.     Add.b    #3,(A0)
  171.     Add.w    #24,a0
  172.     Dbf    D7,SpriteLoop2
  173.     Lea    Sprite2+1,A0
  174.     Move.l    #9,d7
  175. SpriteLoop3
  176.     Add.b    #1,(A0)
  177.     Add.w    #24,a0
  178.     Add.b    #2,(A0)
  179.     Add.w    #24,a0
  180.     Dbf    D7,SpriteLoop3
  181.     Rts
  182.  
  183.  
  184. *****************************************************************************
  185.  
  186. Clear
  187.     Blitwait                ; Blitter Nasty But Why Do
  188.     Move.l    #$01000000,Bltcon0(a5)        ; Clear
  189.     Move.w    #$0000,Bltdmod(a5)        ; Skip No Bytes
  190.     Move.l    ScreenPtr,A1
  191.     Move.l    a1,Bltdpth(A5)            ; Set Dest
  192.     Move.l    #-1,Bltafwm(a5)            ; Use All Bits
  193.     Move.w    #100*64+24,Bltsize(a5)        ; Fill Half Screen
  194.     Movem.l    a0-a6/d0-d7,-(a7)        ; Save The Regs
  195.     Movem.l    RegFiller(pc),a1-a6/d0-d7    ; Clear The Regs
  196.     Move.l    ScreenPtr,A0
  197.     Add.l    #9600,A0
  198.  
  199. ; 4800/56 = 85.71 Rnd Up = 86
  200.     Rept    86                ; Rept it 58 times
  201.     Movem.l    a1-a6/d0-d7,-(a0)        ; Clear 56 Butes
  202.     Endr                    ; End repeat
  203.     Movem.l    (a7)+,a0-a6/d0-d7        ; Restor Regs
  204.     Rts
  205. RegFiller
  206.     Dcb.l    16,0
  207.     Rts
  208.     
  209. *****************************************************************************
  210.  
  211. SetNights
  212.     Cmp.b    #45,BarPos1
  213.     Beq.s    LeaveBarPos1
  214.     Add.b    #1,BarPos1
  215. LeaveBarPos1
  216.     Cmp.b    #113,BarPos2
  217.     Beq.s    LeaveBarPos2
  218.     Add.b    #2,BarPos2
  219.     Lea    BlueFade+2,A0
  220.     Move.l    #6-1,d7
  221.     Move.l    #2,d6
  222.     Move.l    #4,d5
  223.     Move.l    #StarFade1,A1
  224.     Bsr    FadeLoop
  225. LeaveBarPos2
  226.     Cmp.b    #40,BarPos3
  227.     Beq.s    LeaveBarPos3
  228.     Sub.b    #1,BarPos3
  229. LeaveBarPos3
  230.     Rts
  231.  
  232. SetNights1
  233.     Cmp.b    #35,BarPos1
  234.     Beq.s    LeaveBarPos1a
  235.     Sub.b    #1,BarPos1
  236. LeaveBarPos1a
  237.     Cmp.b    #35,BarPos2
  238.     Beq.s    LeaveBarPos2a
  239.     Sub.b    #2,BarPos2
  240. LeaveBarPos2a
  241.     Cmp.b    #60,BarPos3
  242.     Beq.s    LeaveBarPos3a
  243.     Add.b    #1,BarPos3
  244. LeaveBarPos3a
  245.     Rts
  246.     
  247. *****************************************************************************
  248.  
  249. Fading    
  250.     Tst.w    Shafting
  251.     Beq.s    GoShaft
  252.     Sub.w    #1,Shafting
  253.     Rts
  254. GoShaft
  255.     Move.w    #Fadespeed,Shafting        ; Fade Del
  256.     Bsr    TstSomeShit
  257.     Lea    FadeDest+2,A0
  258.     Move.l    FadePtr,A1
  259.     Move.l    #8-1,D7
  260.     Move.l    #2,D6
  261.     Move.l    #4,D5
  262. FadeLoop
  263.     Move.w    (a0),d0                ; Current Colour
  264.     Move.w    (a1),d1                ; What Colour Do We Want
  265.     Bsr    DoFade
  266.     Move.w    d4,(a0)                ; Store New Col
  267.     Add.w    d5,a0
  268.     Add.w    d6,a1
  269.     Dbf    D7,FadeLoop
  270.     Rts
  271. DoFade
  272.     Move.w    d0,D2
  273.     Move.w    d1,d3
  274.     And.w    #$00f,D2            ; Get Blue
  275.     And.w    #$00f,D3            ; Get Blue
  276.     Cmp.w    d2,d3                ; Check Both
  277.     Blt.s    FadeBlueDown            ; If Lower Add
  278.     Bgt.s    FadeBlueUp            ; If Higher Sub
  279.     Bra    LeaveBlue            ; Or Leave Alone
  280. FadeBlueUp
  281.     Add.w    #$001,D2            ; Add To The Blue
  282.     Bra    LeaveBlue            
  283. FadeBluedown
  284.     Sub.w    #$001,D2            ; Sub From The Blue
  285.     Bra    LeaveBlue
  286. LeaveBlue
  287.     Move.w    D2,D4                ; Store It
  288.     Move.w    d0,D2
  289.     Move.w    d1,d3
  290.     And.w    #$0f0,D2            ; Get Green
  291.     And.w    #$0f0,D3            ; Get Green
  292.     Cmp.w    d2,d3                ; Check Both
  293.     Blt.s    FadeGreenDown
  294.     Bgt.s    FadeGreenUp
  295.     Bra    LeaveGreen
  296. FadeGreenUp
  297.     Add.w    #$010,D2
  298.     Bra    LeaveGreen
  299. FadeGreendown
  300.     Sub.w    #$010,D2
  301.     Bra    LeaveGreen
  302. LeaveGreen
  303.     Or.w    D2,D4
  304.     Move.w    d0,D2
  305.     Move.w    d1,d3
  306.     And.w    #$f00,D2            ; Get Red
  307.     And.w    #$f00,D3            ; Get Red
  308.     Cmp.w    d2,d3                ; Check Both
  309.     Blt.s    FadeRedDown
  310.     Bgt.s    FadeRedUp
  311.     Bra    LeaveRed
  312. FadeRedUp
  313.     Add.w    #$100,D2
  314.     Bra    LeaveRed
  315. FadeReddown
  316.     Sub.w    #$100,D2
  317.     Bra    LeaveRed
  318. LeaveRed
  319.     Or.w    D2,D4
  320.     Rts
  321.  
  322. TstSomeShit
  323.     Tst.l    ShaftDel
  324.     Beq.s    DoTheDoFade    
  325.     Sub.l    #1,ShaftDel
  326.     Rts
  327. DoTheDoFade    
  328.     Move.l    #16+(100/Fadespeed),ShaftDel
  329.     Move.l    ShaftPtr,A0
  330.     Move.l    (a0)+,d0
  331.     Cmp.l    #-1,d0
  332.     Bne.s    OkShaft
  333.     Move.l    #ShaftTab,A0
  334.     Move.l    (a0)+,d0
  335. OkShaft
  336.     Move.l    A0,ShaftPtr
  337.     Move.l    D0,FadePtr
  338.     Rts
  339.     
  340. *****************************************************************************
  341.  
  342. Riders
  343.     Move.l    NightColPtr,A0
  344.     Add.l    #2,A0
  345.     Cmp.l    #NightCols+NightColsize,A0
  346.     Blt.s    RiderNoEnd
  347.     Move.l    #NightCols,A0
  348. RiderNoEnd
  349.     Move.l    A0,NightColPtr
  350.     Move.l    A0,Bltapth(a5)
  351.     Move.l    #Night1+2,Bltdpth(a5)
  352.     Move.l    #$ffffffff,Bltafwm(a5)
  353.     Move.l    #$09f00000,Bltcon0(a5)
  354.     Move.w    #$0000,Bltamod(a5)
  355.     Move.w    #$0002,Bltdmod(a5)
  356.     Move.w    #46*64+1,Bltsize(a5)
  357.     Move.w    #-4,Bltamod(a5)
  358.     Move.l    #Night2+2,Bltdpth(a5)
  359.     Move.w    #46*64+1,Bltsize(a5)
  360.     Move.w    #0,Bltamod(a5)
  361.     Move.l    #Night3+2,Bltdpth(a5)
  362.     Move.w    #46*64+1,Bltsize(a5)
  363.     Rts
  364.  
  365. *****************************************************************************
  366.  
  367. X1Inc    Dc.w    0
  368. X2Inc    Dc.w    0
  369. Sin1Inc    Dc.w    0
  370. Sin2Inc    Dc.w    0
  371. Sin1Pt    Dc.w    0
  372. Sin2Pt    Dc.w    0
  373.  
  374. SineOn
  375.     Dc.l    0            ; 1 = Sine
  376. SineSmth
  377.     Dc.w    0
  378.     
  379. SinTab
  380.     Include    Source/0-50sin
  381.     Include    Source/0-50sin
  382.     Include    Source/0-50sin
  383.     Include    Source/0-50sin
  384.  
  385. *****************************************************************************
  386.  
  387. DoScroll
  388.     Tst.l    SineOn
  389.     Beq    NoSine
  390.     Tst.w    SineSmth
  391.     Bne    ScrollOnSine
  392.     Move.w    #8,SineSmth
  393.     Clr.l    D0
  394.     Move.l    ScrollPtr,A0
  395.     Move.b    (a0)+,D0
  396.     Cmp.b    #-1,D0
  397.     Bne.s    NoSineEnd
  398.     Move.l    #ScrollText,A0
  399.     Move.b    (a0)+,d0
  400. NoSineEnd
  401.     Cmp.b    #253,D0
  402.     Bne.s    SineBack
  403.     Move.l    #0,SineOn
  404.     Move.b    (a0)+,d0
  405. SineBack
  406.     Move.l    A0,ScrollPtr
  407.     Sub.b    #32,d0                
  408.     Divu    #20,d0                
  409.     Move.w    d0,d1                
  410.     Mulu    #40*16,d1            
  411.     Swap    d0                
  412.     Add.w    d0,d0                
  413.     Add.w    d0,d1                
  414.     Lea    Font,A2
  415.     Add.w    D1,A2
  416.     Move.l    A2,Bltapth(A5)
  417.     Move.l    #$7a000+46,Bltdpth(A5)
  418.     Move.w    #38,Bltamod(A5)
  419.     Move.w    #46,Bltdmod(A5)
  420.     Move.l    #-1,Bltafwm(A5)
  421.     Move.l    #$09f00000,Bltcon0(a5)
  422.     Move.w    #16*64+1,Bltsize(A5)
  423. ScrollOnSine
  424.     Sub.w    #1,SineSmth
  425.     Move.l    #$7a002,Bltapth(A5)
  426.     Move.l    #$7a000,Bltdpth(A5)
  427.     Move.w    #0,Bltamod(A5)
  428.     Move.w    #0,Bltdmod(A5)
  429.     Move.l    #-1,Bltafwm(A5)
  430.     Move.l    #$e9f00000,Bltcon0(a5)
  431.     Move.w    #16*64+24,Bltsize(A5)
  432.  
  433.     Move.w    #46,Bltamod(a5)
  434.     Move.w    #46,Bltcmod(a5)
  435.     Move.w    #46,Bltdmod(a5)
  436.     Move.l    #$0bfa0000,Bltcon0(a5)
  437.     Move.l    #-1,Bltafwm(a5)
  438.     Move.l    Sin1Inc,D7
  439.     Add.l    D7,Sin1pt
  440.     And.l    #$07fe07fe,Sin1pt
  441.     Lea    Bltapth(a5),A1
  442.     Lea    Bltcpth(a5),A2
  443.     Lea    Bltdpth(a5),A3
  444.     Lea    Bltsize(a5),A4
  445.     Lea    Bltafwm(a5),A6
  446.     Lea    SinTab,A0
  447.     Add.w    Sin1pt,A0
  448.     Lea    Sintab,A5
  449.     Add.w    Sin2pt,A5
  450.     Move.l    #$7a000,D0
  451.     Move.l    ScreenPtr,D1
  452.     Add.w    #4,D1
  453.     Move.w    #16*64+1,D2
  454.     Moveq    #0,D3
  455.     Moveq    #0,D4
  456.     Move.w    X1inc,D5
  457.     Move.w    X2inc,D6
  458. BlitMac    Macro
  459.     Add.w    (a0,d3),d1
  460.     Add.w    (a5,d4),d1
  461.     Move.l    D0,(a1)
  462.     Move.l    D1,(a2)    
  463.     Move.l    D1,(a3)    
  464.     Move.w    #\1,(a6)
  465.     Move.w    D2,(a4)
  466.     Sub.w    (a0,d3),d1
  467.     Sub.w    (a5,d4),d1
  468.     Add.w    D5,D3
  469.     Add.w    D6,D4
  470.     Endm
  471.     Rept    20
  472.     BlitMac    $8000
  473.     BlitMac    $4000
  474.     BlitMac    $2000
  475.     BlitMac    $1000
  476.     BlitMac    $0800
  477.     BlitMac    $0400
  478.     BlitMac    $0200
  479.     BlitMac    $0100
  480.     BlitMac    $0080
  481.     BlitMac    $0040
  482.     BlitMac    $0020
  483.     BlitMac    $0010
  484.     BlitMac    $0008
  485.     BlitMac    $0004
  486.     BlitMac    $0002
  487.     BlitMac    $0001
  488.     Add.w    #2,D0
  489.     Add.w    #2,D1
  490.     Endr
  491.     Lea    Custom,A5
  492.     Rts
  493.     
  494. NoSine
  495.     Rept    ScrollSpeed
  496.     Bsr    ScrityPel
  497.     Endr
  498.     Tst.w    ScrollS
  499.     Bne    Sctrollon
  500.     Moveq    #0,D0
  501.     Move.l    ScrollPtr,A0
  502.     Move.b    (a0)+,d0
  503.     Cmp.b    #-1,d0
  504.     Bne.s    ScrollEnd
  505.     Move.l    #ScrollText,A0
  506.     Move.b    (a0)+,d0
  507. ScrollEnd    
  508.     Cmp.b    #254,d0
  509.     Bne.s    NoSineing
  510.     Move.l    #1,SineOn
  511.     Move.b    (a0)+,X1inc+1
  512.     Move.b    (a0)+,X2inc+1
  513.     Move.b    (a0)+,Sin1Inc+1
  514.     Move.b    (a0)+,Sin2Inc+1
  515.     Move.b    (a0)+,D0
  516. NoSineing
  517.     Cmp.b    #253,D0
  518.     Bne.s    SineOff
  519.     Move.l    #0,SineOn
  520.     Move.b    (a0)+,D0
  521. SineOff
  522.     Move.l    A0,ScrollPtr
  523.     Sub.b    #32,d0
  524.     Muls    #30,d0
  525.     Lea    CharTab,A0
  526.     Add.l    D0,A0
  527.     Lea    CurChar,A1
  528.     Move.l    #29,D7
  529. Shift
  530.     Move.b    (a0)+,(a1)+
  531.     Dbf    D7,Shift
  532.     Move.w    #6,ScrollS
  533. Sctrollon
  534.     Add.w    #4,Yptr
  535.     And.w    #255,Yptr
  536.     Add.w    #4,xptr
  537.     And.w    #127,xptr
  538.     Clr.l    d0
  539.     Clr.l    d1
  540.     Clr.l    d2
  541.     Clr.l    d3
  542.     Move.l    ScreenPtr,A0
  543.     Lea    BobInfo,A1
  544.     Lea    Ytab,A2
  545.     Add.w    Yptr,A2
  546.     Lea    Xtab,A3
  547.     Add.w    Xptr,A3
  548.     Lea    CharSpace,A6
  549.     Move.w    #44,Bltcmod(A5)
  550.     Move.w    #44,Bltdmod(A5)
  551.     Move.w    #-2,Bltamod(A5)
  552.     Move.l    #$ffff0000,Bltafwm(a5)
  553.     Move.l    #$0bfa0000,Bltcon0(a5)
  554.     Move.w    #21,D7
  555.     Move.w    SnurkScroll,D1            ; X
  556. BlitLoop
  557.     Move.w    #5-1,d6                ; Down
  558. BlitLoop1
  559.     Addq    #2,a2
  560.     Addq    #2,a3
  561.     Move.b    (a6)+,d0
  562.     Cmp.b    #" ",d0
  563.     Beq.s    SkipBlit
  564.     Movem.l    d1-d2/a0,-(a7)
  565.     Add.w    (a3),d1
  566.     Ror.l    #4,D1
  567.     Add.w    d1,d1
  568.     Add.w    (a2),d2
  569.     Add.w    D1,A0
  570.     Add.w    D2,A0
  571.     Swap    D1
  572.     Or.w    #$0bfa,D1
  573.     Move.w    d1,Bltcon0(a5)
  574.     Move.l    A1,Bltapth(a5)
  575.     Move.l    A0,Bltcpth(a5)
  576.     Move.l    A0,Bltdpth(a5)
  577.     Move.w    #16*64+2,Bltsize(a5)
  578.     Movem.l    (a7)+,d1-d2/a0
  579. SkipBlit
  580.     Add.w    #16*48,d2
  581.     Dbf    D6,BlitLoop1
  582.     Sub.w    #6,A3
  583.     Moveq    #0,D2
  584.     Add.w    #16,d1
  585.     Dbf    D7,BlitLoop
  586.     Rts
  587.  
  588. ScrityPel
  589.     Sub.w    #2,SnurkScroll
  590.     Cmp.w    #0,SnurkScroll
  591.     Bgt.s    GoSub
  592.     Move.w    #15,SnurkScroll
  593.     Lea    CharSpace,A0
  594.     Lea    CharSpace+5,A1
  595.     Move.l    #(6*6)-2,d7
  596.     Sub.w    #1,ScrollS
  597. ShiftLoop
  598.     Move.b    (a1)+,(a0)+
  599.     Move.b    (a1)+,(a0)+
  600.     Move.b    (a1)+,(a0)+
  601.     Move.b    (a1)+,(a0)+
  602.     Move.b    (a1)+,(a0)+
  603.     Dbf    D7,ShiftLoop
  604.     Add.w    #8,yptr
  605.     Add.w    #4,Xptr
  606. GoSub
  607.     Rts
  608.  
  609. *****************************************************************************
  610.  
  611. SnurkScroll
  612.     Dc.w    15
  613. ScreenPtr
  614.     Dc.l    $70000
  615.     
  616. *****************************************************************************
  617.  
  618. ScrollS
  619.     Dc.w    0
  620. YPtr
  621.     Dc.w    0
  622. YTab
  623.     Rept    2
  624.     dc.w    96*48,96*48,96*48,95*48,95*48,95*48,94*48,93*48
  625.     dc.w    92*48,91*48,90*48,89*48,88*48,87*48,85*48,84*48
  626.     dc.w    82*48,80*48,78*48,77*48,75*48,73*48,71*48,69*48
  627.     dc.w    66*48,64*48,62*48,60*48,57*48,55*48,53*48,50*48
  628.     dc.w    48*48,46*48,43*48,41*48,39*48,36*48,34*48,32*48
  629.     dc.w    30*48,27*48,25*48,23*48,21*48,19*48,18*48,16*48
  630.     dc.w    14*48,12*48,11*48,9*48,8*48,7*48,6*48,5*48
  631.     dc.w    4*48,3*48,2*48,1*48,1*48,1*48,0*48,0*48
  632.     dc.w    0*48,0*48,0*48,1*48,1*48,1*48,2*48,3*48
  633.     dc.w    4*48,5*48,6*48,7*48,8*48,9*48,11*48,12*48
  634.     dc.w    14*48,16*48,18*48,19*48,21*48,23*48,25*48,27*48
  635.     dc.w    30*48,32*48,34*48,36*48,39*48,41*48,43*48,46*48
  636.     dc.w    48*48,50*48,53*48,55*48,57*48,60*48,62*48,64*48
  637.     dc.w    66*48,69*48,71*48,73*48,75*48,77*48,78*48,80*48
  638.     dc.w    82*48,84*48,85*48,87*48,88*48,89*48,90*48,91*48
  639.     dc.w    92*48,93*48,94*48,95*48,95*48,95*48,96*48,96*48
  640.     Endr
  641.  
  642. XPtr
  643.     Dc.w    0
  644. Xtab
  645.     Rept    7
  646.     dc.w    15,15,15,15,14,14,14,13
  647.     dc.w    13,12,12,11,10,10,9,8
  648.     dc.w    7,7,6,5,5,4,3,3
  649.     dc.w    2,2,1,1,1,0,0,0
  650.     dc.w    0,0,0,0,1,1,1,2
  651.     dc.w    2,3,3,4,5,5,6,7
  652.     dc.w    7,8,9,10,10,11,12,12
  653.     dc.w    13,13,14,14,14,15,15,15
  654.     Endr
  655.  
  656. *****************************************************************************
  657.  
  658. CharSpace
  659.     Rept    5
  660.     Dc.b    "     "
  661.     Dc.b    "     "
  662.     Dc.b    "     "
  663.     Dc.b    "     "
  664.     Dc.b    "     "
  665.     Dc.b    "     "
  666.     Endr
  667. CurChar
  668.     Dc.b    "     "
  669.     Dc.b    "     "
  670.     Dc.b    "     "
  671.     Dc.b    "     "
  672.     Dc.b    "     "
  673.     Dc.b    "     "
  674.  
  675. CharTab 
  676.     Include    Source/SnurkFnt2
  677.  even
  678.  
  679. *****************************************************************************
  680.  
  681. ScrollPtr
  682.     Dc.l    ScrollText
  683. ScrollText
  684.     Include    Intro-1/ScrollText
  685.     DC.B    255
  686.  even
  687.  
  688. *****************************************************************************
  689.  
  690. SprMac    Macro
  691.     Dc.b    \1,\2,\1+5,\3
  692.     Dc.w    %01010,%00110
  693.     Dc.w    %11101,%00011
  694.     Dc.w    %11011,%10111
  695.     Dc.w    %11111,%11111
  696.     Dc.w    %01110,%01110
  697.     Endm
  698. SprMac1    Macro
  699.     Dc.b    \1,\2,\1+5,\3
  700.     Dc.w    %00000,%01000
  701.     Dc.w    %01000,%10100
  702.     Dc.w    %00000,%01000
  703.     Dc.w    %00000,%00000
  704.     Dc.w    %00000,%00000
  705.     Endm
  706. SprMac2    Macro
  707.     Dc.b    \1,\2,\1+5,\3
  708.     Dc.w    %00000,%00000
  709.     Dc.w    %01000,%00000
  710.     Dc.w    %00000,%00000
  711.     Dc.w    %00000,%00000
  712.     Dc.w    %00000,%00000
  713.     Endm
  714.  
  715. *****************************************************************************
  716.  
  717. Sprite
  718.     SprMac    117,028,0
  719.     SprMac    127,172,0
  720.     SprMac    137,058,0
  721.     SprMac    147,207,0
  722.     SprMac    157,135,0
  723.     SprMac    167,092,0
  724.     SprMac    177,073,0
  725.     SprMac    187,126,0
  726.     SprMac    197,144,0
  727.     SprMac    207,028,0
  728.     SprMac    217,213,0
  729.     SprMac    227,166,0
  730.     SprMac    237,012,0
  731.     SprMac    247,213,0
  732.     SprMac    002,093,6
  733.     SprMac    012,122,6
  734.     SprMac    022,051,6
  735.     SprMac    032,134,6
  736.     Dcb.w    20,0
  737. Sprite1
  738.     SprMac1    117,209,0
  739.     SprMac1    127,187,0
  740.     SprMac1    137,113,0
  741.     SprMac1    147,090,0
  742.     SprMac1    157,213,0
  743.     SprMac1    167,015,0
  744.     SprMac1    177,026,0
  745.     SprMac1    187,129,0
  746.     SprMac1    197,160,0
  747.     SprMac1    207,171,0
  748.     SprMac1    217,075,0
  749.     SprMac1    227,130,0
  750.     SprMac1    237,096,0
  751.     SprMac1    247,166,0
  752.     SprMac1    002,097,6
  753.     SprMac1    012,169,6
  754.     SprMac1    022,083,6
  755.     SprMac1    032,182,6
  756.     Dcb.w    20,0
  757. Sprite2
  758.     SprMac2    117,035,0
  759.     SprMac2    127,014,0
  760.     SprMac2    137,094,0
  761.     SprMac2    147,028,0
  762.     SprMac2    157,095,0
  763.     SprMac2    167,140,0
  764.     SprMac2    177,105,0
  765.     SprMac2    187,186,0
  766.     SprMac2    197,147,0
  767.     SprMac2    207,035,0
  768.     SprMac2    217,114,0
  769.     SprMac2    227,085,0
  770.     SprMac2    237,249,0
  771.     SprMac2    247,088,0
  772.     SprMac2    002,080,6
  773.     SprMac2    012,004,6
  774.     SprMac2    022,063,6
  775.     SprMac2    032,253,6
  776.     Dcb.w    20,0
  777.     
  778. *****************************************************************************
  779.  
  780. ; All copper list after here
  781.  
  782. Copper
  783.     Spr_Off                    ; Switch sprites off
  784.     Cmove    $0003,Bplcon2
  785. Spr0l    Cmove    $0000,Spr0ptl
  786. Spr0h    Cmove    $0000,Spr0pth
  787. Spr1l    Cmove    $0000,Spr1ptl
  788. Spr1h    Cmove    $0000,Spr1pth
  789. Spr2l    Cmove    $0000,Spr2ptl
  790. Spr2h    Cmove    $0000,Spr2pth
  791.     Cmove    $2c81,Diwstrt
  792.     Cmove    $2cc1,Diwstop
  793.     Cmove    $0038,Ddfstrt
  794.     Cmove    $00d0,Ddfstop
  795.     Cmove    $0000,Bplcon1
  796.     Cmove    $0000,Bpl1mod            
  797.     Cmove    $0000,Bpl2mod
  798. LogoBits
  799.     Cmove    $0000,Bpl1ptl
  800.     Cmove    $0000,Bpl1pth
  801.     Cmove    $0000,Bpl2ptl
  802.     Cmove    $0000,Bpl2pth
  803.     Cmove    $0000,Bpl3ptl
  804.     Cmove    $0000,Bpl3pth
  805.     Cmove    $3200,Bplcon0
  806. Barpos1
  807.     Cwait    20,40                ; 45
  808. Night1
  809.     Rept    47
  810.     Cmove    $0000,color00
  811.     Endr
  812. FadeDest
  813.     Cmove    $0000,Color00
  814.     Cmove    $0fff,Color01
  815.     Cmove    $0eee,Color02
  816.     Cmove    $0ddd,Color03
  817.     Cmove    $0ccc,Color04
  818.     Cmove    $0bbb,Color05
  819.     Cmove    $0aaa,Color06
  820.     Cmove    $0999,Color07
  821. Barpos2
  822.     Cwait    35,40                ; 113
  823. Night2
  824.     Rept    47
  825.     Cmove    $0000,color00
  826.     Endr
  827.     Cmove    $0000,Color00
  828.     Cmove    $0200,Bplcon0
  829.  
  830.     Cwait    118,0
  831.     Cmove    $2200,Bplcon0
  832. Buff1
  833.     Cmove    $0004,Bpl1ptl
  834.     Cmove    $0007,Bpl1pth
  835. Buff2
  836.     Cmove    $0004+48,Bpl2ptl
  837.     Cmove    $0007,Bpl2pth
  838. SnurkCol
  839.     Cmove    $0666,Color01
  840.     Cmove    $0fff,Color02
  841.     Cmove    $0aaa,Color03
  842.     Cmove    $0008,Bpl1mod            
  843.     Cmove    $0008,Bpl2mod
  844.     Cmove    $0001,Bplcon1
  845.     Cmove    $0000,Color16
  846. BlueFade
  847.     Cmove    $0000,Color17
  848.     Cmove    $0000,Color18
  849.     Cmove    $0000,Color19
  850.     
  851.     Cmove    $0000,Color21
  852.     Cmove    $0000,Color22
  853.     Cmove    $0000,Color23
  854. BAR        Macro
  855.     DC.B     \1,$09,$FF,$FE
  856.     DC.W     COLOR03,\2
  857.     ENDM
  858.  
  859.  
  860. Nit    Bar    120,$0F9
  861.     Bar    122,$0FA
  862.     Bar    124,$0FB
  863.     Bar    126,$0FC
  864.     Bar    128,$0FD
  865.     Bar    130,$0FE
  866.     Bar    132,$0FF
  867.     Bar    134,$0EF
  868.     Bar    136,$0DF
  869.     Bar    138,$0CF
  870.     Bar    140,$0BF
  871.     Bar    142,$0AF
  872.     Bar    144,$09F
  873.     Bar    146,$08F
  874.     Bar    148,$07F
  875.     Bar    150,$06F
  876.     Bar    152,$05F
  877.     Bar    154,$04F
  878.     Bar    156,$03F
  879.     Bar    158,$02F
  880.     Bar    160,$01F
  881.     Bar    162,$00F
  882.     Bar    164,$10F
  883.     Bar    166,$20F
  884.     Bar    168,$30F
  885.     Bar    170,$40F
  886.     Bar    172,$50F
  887.     Bar    174,$60F
  888.     Bar    176,$70F
  889.     Bar    178,$80F
  890.     Bar    180,$90F
  891.     Bar    182,$A0F
  892.     Bar    184,$B0F
  893.     Bar    186,$C0F
  894.     Bar    188,$D0F
  895.     Bar    190,$E0F
  896.     Bar    192,$F0F
  897.     Bar    194,$F0E
  898.     Bar    196,$F0D
  899.     Bar    198,$F0C
  900.     Bar    200,$F0B
  901.     Bar    212,$F0A
  902.     Bar    214,$F09
  903.     Bar    216,$F08
  904.     Bar    218,$F07
  905.     Bar    220,$F06
  906.     Bar    222,$F05
  907.     Bar    224,$F04
  908.     Bar    226,$F03
  909.     Bar    228,$F02
  910.     Bar    230,$F01
  911.     Bar    232,$F00
  912.     Bar    234,$F10
  913.     Bar    236,$F20
  914.     Bar    238,$F30
  915.     Bar    240,$F40
  916.     Bar    242,$F50
  917.     Bar    244,$F60
  918.     Bar    246,$F70
  919.     Bar    248,$F80
  920.     Bar    250,$F90
  921.     Bar    252,$FA0
  922.     Bar    254,$FB0
  923.     DC.W    $FFDD,$FFFE
  924.     Dc.w    Color03,$fb0
  925.     Bar    1,$FC0
  926.     Bar    3,$FD0
  927.     Bar    5,$FE0
  928.     Bar    7,$FF0
  929.     Bar    9,$EF0
  930.     Bar    11,$DF0
  931.     Bar    13,$CF0
  932.     Bar    15,$BF0
  933.     Bar    17,$AF0
  934.     Bar    19,$9F0
  935.     Bar    21,$8F0
  936.     Bar    23,$7F0
  937.     Bar    25,$6F0
  938.     Bar    27,$5F0
  939.     Bar    29,$4F0
  940.     Bar    31,$3F0
  941.     Bar    33,$2F0
  942.     Bar    35,$1F0
  943.     Bar    37,$0F0
  944.     Bar    39,$0E0
  945. Barpos3
  946.     Cwait    60,40                ; 113
  947. Night3
  948.     Rept    47
  949.     Cmove    $0000,color00
  950.     Endr
  951.     Cmove    $0000,Color00
  952.     Endcop
  953.  
  954. *****************************************************************************
  955.  
  956. FadePtr
  957.     Dc.l    FadeCol2
  958.     
  959. *****************************************************************************
  960.  
  961. ShaftPtr
  962.     Dc.l    ShaftTab
  963. ShaftTab
  964.     Dc.l    FadeCol1                ; Fade This Lot
  965.     Dc.l    FadeCol2                ; Fade This Lot
  966.     Dc.l    FadeCol3                ; Fade This Lot
  967.     Dc.l    FadeCol4
  968.     dc.l    fadecol5
  969.     dc.l    fadecol6
  970.     dc.l    fadecol7
  971.     dc.l    fadecol8
  972.     dc.l    fadecol9        
  973.     Dc.l    -1
  974. ShaftDel
  975.     Dc.l    0
  976. Shafting
  977.     Dc.w    0
  978.     
  979. *****************************************************************************
  980.  
  981. FadeCol1
  982.     Dc.w    $111,$0cf,$0ad,$08b,$079,$068,$046,$034    ; Fade Cols
  983. FadeCol2
  984.     Dc.w    $111,$c0f,$a0d,$80b,$709,$608,$406,$304    ; Fade Cols
  985. FadeCol3
  986.     Dc.w    $111,$0ff,$0dd,$0bb,$099,$077,$055,$033    ; Fade Cols
  987. FadeCol4
  988.     Dc.w    $111,$fff,$ddd,$bbb,$999,$778,$556,$334    ; Fade Cols
  989. FadeCol5
  990.     Dc.w    $111,$f47,$d03,$b03,$902,$802,$601,$401    ; Fade Cols
  991. FadeCol6
  992.     Dc.w    $111,$4f3,$1d0,$1b0,$190,$070,$050,$030    ; Fade Cols
  993. FadeCol7
  994.     Dc.w    $111,$f81,$c60,$a50,$940,$740,$630,$420    ; Fade Cols
  995. FadeCol8
  996.     Dc.w    $111,$71f,$50c,$40a,$308,$307,$205,$203    ; Fade Cols
  997. FadeCol9
  998.     Dc.w    $111,$ef1,$bc0,$9a0,$780,$670,$450,$340    ; Fade Cols
  999. StarFade1
  1000.     Dc.w    $00f,$00a,$005,$00f,$00a,$005
  1001. FadeDown
  1002.     Dc.w    $000,$000,$000,$000,$000,$000,$000,$000
  1003.         
  1004. *****************************************************************************
  1005.  
  1006. NightColPtr
  1007.     Dc.l    NightCols
  1008. NightCols
  1009. ; Colours To Go Through Night Rider
  1010.     Rept    2
  1011.     Dc.w    $f00,$f01,$f02,$f03,$f04
  1012.     Dc.w    $f05,$f06,$f07,$f08,$f09,$f0a,$f0b,$f0c,$f0d,$f0e
  1013.     Dc.w    $f0f,$e1f,$d2f,$c3f,$b4f,$a5f,$96f,$87f,$78f,$69f
  1014.     Dc.w    $5af,$4bf,$3cf,$2df,$1ef,$0ff,$1fe,$2fd,$3fc,$4fb
  1015.     Dc.w    $5fa,$6f9,$7f8,$8f7,$9f6,$af5,$bf4,$cf3,$df2,$ef1
  1016.     Dc.w    $ff0,$ff1,$ff2,$ff3,$ff4,$ff5,$ff6,$ff7,$ff8,$ff9
  1017.     Dc.w    $ffa,$ffb,$ffc,$ffd,$ffe,$fff,$fee,$fdd,$fcc,$fbb
  1018.     Dc.w    $faa,$f99,$f88,$f77,$f66,$f55,$f44,$f33,$f22,$f11
  1019.     Endr
  1020. NightColsize=(*-Nightcols)/2
  1021.  
  1022. *****************************************************************************
  1023.  
  1024. BobInfo
  1025.     Dc.w    %0011111111111100
  1026.     Dc.w    %0111111111111110
  1027.     Dc.w    %1110000000000111
  1028.     Dc.w    %1101111111111011
  1029.     Dc.w    %1101111111111011
  1030.     Dc.w    %1101111111111011
  1031.     Dc.w    %1101111111111011
  1032.     Dc.w    %1101111111111011
  1033.     Dc.w    %1101111111111011
  1034.     Dc.w    %1101111111111011
  1035.     Dc.w    %1101111111111011
  1036.     Dc.w    %1101111111111011
  1037.     Dc.w    %1101111111111011
  1038.     Dc.w    %1101111111111011
  1039.     Dc.w    %1110000000000111
  1040.     Dc.w    %0111111111111110
  1041.     Dc.w    %0011111111111100
  1042.  
  1043. *****************************************************************************
  1044.  
  1045. Logo
  1046.     Incbin    Gfx/Fade70
  1047.     
  1048. *****************************************************************************
  1049.  
  1050. Font
  1051.     Incbin    Gfx/FX-FONT2.bm
  1052.  
  1053.  Even
  1054.  
  1055. *****************************************************************************
  1056.  
  1057.     Include    Source/Future.s
  1058. Bpsong    incbin "Snd/cybermix"
  1059.  
  1060. *****************************************************************************
  1061.  
  1062.